Forwarded: EDIF Version 4 0 0 changes

To IBIS Committee:

Does anyone have any comments or concerns about this?

Bob Ross
Interconnectix, Inc.

Date: Tue, 27 Aug 1996 13:39:51 +0100
From: Alan R Williams <alanrw@cs.man.ac.uk>
Message-Id: <199608271239.NAA04794@cheetah.cs.man.ac.uk>
To: bob@icx.com
Subject: EDIF Version 4 0 0 changes

Hello Bob,

As part of finishing the EIA balloting process, we are notifying all
reviewers of the changes which were made as a result of their
comments. With regard to the interfacing with IBIS files, the main
change has been the introduction on pcbPartCharacteristic for EDIF
parts. The pcbPartCharacteristic can be either a
pcbPassivePartCharacteristic (RLC values) or a
pcbIbisPartCharacteristic which specifies the IBIS file, the IBIS
component within that file and matches up the terminals of the EDIF
part to the pins of the IBIS component.

I am enclosing the changes in the syntax which were made as a result
of your comment. Could you please confirm by c.o.b. Friday 31st
August that you are satisfied with the outcome? If we do not hear
otherwise, we will assume that you are satisfied with the changes
which have been made.

Alan Williams

-- ---------------------------------------------------------------------------
Alan Williams, Room IT301, Department of Computer Science,
University of Manchester, Oxford Road, Manchester, M13 9PL, U.K.
Tel: +44 161 275 6270 Fax: +44 161 275 6280
e-mail: alanrw@cs.man.ac.uk

pcbIbisComponentIdentification ::= '(' 'pcbIbisComponentIdentification'
        stringToken
        ')'

pcbIbisFileIdentification ::= '(' 'pcbIbisFileIdentification'
        stringToken
        ')'

pcbIbisFileInformation ::= '(' 'pcbIbisFileInformation'
        pcbIbisFileInformationNameDef
        pcbIbisFileIdentification
        { <nameInformation> | property }
        ')'

pcbIbisFileInformationNameCaseSensitive ::= '('
'pcbIbisFileInformationNameCaseSensitive'
        booleanToken
        ')'

pcbIbisFileInformationNameDef ::= nameDef

pcbIbisPartCharacteristic ::= '(' 'pcbIbisPartCharacteristic'
        pcbIbisFileInformation
        pcbIbisComponentIdentification
        { pcbIbisPinBinding }
        ')'

pcbIbisPinBinding ::= '(' 'pcbIbisPinBinding'
        pcbIbisPinBindingNameDef
        ( pcbElectricalPartTerminalRef | pcbJumperPartTerminalRef |
pcbConnectorPartTerminalRef )
        pcbIbisPinIdentification
        { property }
        ')'

pcbIbisPinBindingNameDef ::= nameDef

pcbIbisPinIdentification ::= '(' 'pcbIbisPinIdentification'
        stringToken
        ')'

pcbJumperPart ::= '(' 'pcbJumperPart'
        libraryObjectNameDef
        pcbPartHeader
        ( pcbPinPackageRef | pcbBallPackageRef | externalNoData )
        { pcbJumperPartTerminal | <pcbPartCharacteristic> }
        ')'

pcbPackagedConnectorPart ::= '(' 'pcbPackagedConnectorPart'
        libraryObjectNameDef
        pcbPartHeader
        ( pcbPinPackageRef | pcbBallPackageRef | externalNoData )
        ( pcbSocket | pcbDiscreteConnector )
        { pcbPackagedConnectorPartTerminal | <pcbPartCharacteristic> }
        ')'

pcbPackagedElectricalPart ::= '(' 'pcbPackagedElectricalPart'
        libraryObjectNameDef
        pcbPartHeader
        ( pcbPinPackageRef | pcbBallPackageRef | externalNoData )
        pcbPackagedElectricalPartType
        { <pcbPartCharacteristic> }
        ')'

pcbPartCharacteristic ::= '(' 'pcbPartCharacteristic'
        ( pcbPassivePartCharacteristic | pcbIbisPartCharacteristic )
        ')'

pcbPassivePartCapacitance ::= '(' 'pcbPassivePartCapacitance'
        capacitanceValue
        ')'

pcbPassivePartCharacteristic ::= '(' 'pcbPassivePartCharacteristic'
        { <pcbPassivePartCapacitance> | <pcbPassivePartInductance> |
<pcbPassivePartResistance> }
        ')'

pcbPassivePartInductance ::= '(' 'pcbPassivePartInductance'
        tolerancedInductanceValue
        ')'

pcbPassivePartResistance ::= '(' 'pcbPassivePartResistance'
        tolerancedResistanceValue
        ')'

pcbPrintedConnectorPart ::= '(' 'pcbPrintedConnectorPart'
        libraryObjectNameDef
        pcbPartHeader
        { <pcbPartCharacteristic> | pcbPrintedConnectorPartTerminal |
pcbPrintedPartSymbol }
        ')'

pcbPrintedElectricalPart ::= '(' 'pcbPrintedElectricalPart'
        libraryObjectNameDef
        pcbPartHeader
        pcbPrintedElectricalPartType
        { <pcbPartCharacteristic> | pcbPrintedPartSymbol }
        ')'

-------- End of Forwarded Message
Received on Wed Aug 28 18:05:15 1996